# Maintainer: Troy Engel <troyengel+arch@gmail.com>

pkgname=vidyodesktop
pkgver=3.3.0.027
pkgrel=1
pkgdesc="VidyoDesktop video conferencing client"
arch=('i686' 'x86_64')
url="http://www.vidyo.com"
license=('custom')
install=vidyodesktop.install
options=('emptydirs')
conflicts=('vidyo')
makedepends=('rpmextract')
depends=('alsa-lib' 'libidn' 'libutil-linux' 'libxv' 'mesa-libgl' 'glu'
         'glibc' 'libxfixes' 'libxrandr' 'libxss' 'glib2' 'libsm' 'libice'
         'libxrender' 'fontconfig' 'freetype2' 'libxext' 'libx11' 'libffi'
         'gcc-libs' 'zlib' 'libpng' 'zenity')
optdepends=('flashplugin: Join meetings via web browser')

if [ "$CARCH" == "i686" ]; then
  rpmfilename="VidyoDesktopInstaller-sl5-TAG_VD_3_3_0_027.rpm"
  md5sums=('02e44ed593066c6cca6dd69e165a864b')
elif [ "$CARCH" == "x86_64" ]; then
  rpmfilename="VidyoDesktopInstaller-sl564-TAG_VD_3_3_0_027.rpm"
  md5sums=('ce446bf9f222675891c2437394102d92')
fi
source=("https://demo.vidyo.com/upload/${rpmfilename}")

package() {
  cd "${pkgdir}"
  rpmextract.sh "${srcdir}/${rpmfilename}"
  install -dm1777 "${pkgdir}/opt/vidyo/VidyoDesktop/lic"
  install -Dm0644 "${pkgdir}/opt/vidyo/VidyoDesktop/license.txt" \
    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}