# Maintainer: Troy Engel <troyengel+arch@gmail.com>

pkgbase=petrified
pkgname=('petrified-git' 'petrified-git-systemd')
pkgver=20220918.093707
pkgrel=1
arch=('any')
url="https://git.dwarvenruins.com/tengel/petrified"
license=('GPL3')
options=('emptydirs')
source=("https://git.dwarvenruins.com/tengel/petrified/archive/devel.tar.gz")
md5sums=('SKIP')

pkgver() {
  echo $(date +%Y%m%d.%H%M%S)
}

package_petrified-git() {
  pkgdesc="Bash client to update dynamic DNS at freedns.afraid.org"
  depends=('util-linux' 'coreutils' 'bash' 'iproute2' 'curl')
  backup=('etc/petrified.conf')
  provides=('petrified')
  conflicts=('petrified')
  install=petrified.archinst

  cd "${srcdir}/${pkgbase}"

  # Install the system bits
  make DESTDIR="${pkgdir}" PREFIX=/usr install
}

package_petrified-git-systemd() {
  pkgdesc="Unit files for petrified systemd usage"
  depends=('petrified' 'systemd')
  provides=('petrified-systemd')
  conflicts=('petrified-systemd')

  cd "${srcdir}/${pkgbase}"

  # Systemd files
  make DESTDIR="${pkgdir}" PREFIX=/usr install-systemd
}